consolut - ABAPCALL_METHOD_OLE2 - CALL METHOD OLE2

ABAPCALL_METHOD_OLE2 - CALL METHOD OLE2

Fill RESBD Structure from EBP Component Structure Vendor Master (General Section)
Diese Dokumentation steht unter dem Copyright der SAP AG.

CALL METHOD - OLE

Kurzreferenz

Syntax

CALL METHOD OF ole meth [= rc]
[EXPORTING p1 = f1 p2 = f2 ...]
[NO FLUSH] [QUEUE-ONLY].

Zusätze:

1.... EXPORTING p1 = f1 p2 = f2 ...

2.... NO FLUSH

3.... QUEUE-ONLY

Wirkung

Mit dieser Anweisung wird die Methode meth des Automation-Objekts ole aufgerufen. DasAutomation-Objekt muss mit der speziellen Anweisung CREATEOBJECT für Automation-Objekte erzeugt worden sein. Der Name der Methode muss in einem zeichenartigen Datenobjekt meth angegeben werden.

Der Rückgabewert der externen Methode meth kann in einem Datenobjekt rc abgelegtwerden, für das je nach aufgerufener Methode ein zeichenartiger Datentyp der Länge 8 erwartet wird oder das den Typ ole2_object aus derTypgruppe OLE2 haben muss, um das adressierte Objekt zu übernehmen.

Zusatz 1

... EXPORTING p1 = f1 p2 = f2 ...

Wirkung

Mit dem Zusatz EXPORTING können den Eingabeparametern p1 p2 ... der Automation-MethodeAktualparameter f1 f2 ... zugewiesen werden, wobei sich der Datentyp der Datenobjekte f1 f2 ... nach der Anforderung der Automation-Methode richtet.

Zusatz 2

... NO FLUSH

Zusatz 3

... QUEUE-ONLY

Wirkung

Für die Zusätze NO FLUSH und QUEUE-ONLY gilt die Beschreibung bei der AnweisungCREATE OBJECT.

Systemfelder

sy-subrc	Bedeutung
0	Erfolgreiche Ausführung der Methode meth.
1	Fehlerhafte Kommunikation zum SAP GUI.
2	Fehler beim Aufruf der Methode meth.
3	Fehler beim Setzen einer Eigenschaft.
4	Fehler beim Lesen einer Eigenschaft.

Beispiel

Je nach Auswahl auf dem Selektionsbild können mit diesem Quelltext die Excel-Datei Table.xls im Verzeichnis C:\tempgeöffnet, die Anwendung Word gestartet und beide Anwendungen anschließend wieder geschlossenwerden. Die hierfür verwendeten Automation-Methoden sind in der nachstehenden Tabelle aufgelistet.

Anwendung	Methode	Parameter	Funktion
Excel	Open	Dateiname und Pfad	Öffnen
Excel	Quit	-	Beenden
Word	AppShow	-	Starten
Word	AppClose	-	Beenden

TABLES sscrfields.

DATA: excel TYPE ole2_object,
      word  TYPE ole2_object,
      book  TYPE ole2_object,
      rc    TYPE c LENGTH 8.

SELECTION-SCREEN:
  BEGIN OF SCREEN 100 AS WINDOW TITLE title,
    BEGIN OF LINE,
      PUSHBUTTON  2(12) button_1
                 USER-COMMAND word_start,
      PUSHBUTTON  20(12) button_2
                 USER-COMMAND excel_start,
    END OF LINE,
    BEGIN OF LINE,
      PUSHBUTTON  2(12) button_3
                  USER-COMMAND word_stop,
      PUSHBUTTON  20(12) button_4
                 USER-COMMAND excel_stop,
    END OF LINE,
  END OF SCREEN 100.

START-OF-SELECTION.
  button_1 = 'Start Word'.
  button_2 = 'Start Excel'.
  button_3 = 'Stop  Word'.
  button_4 = 'Stop  Excel'.
  CALL SELECTION-SCREEN 100 STARTING AT 10 10.

AT SELECTION-SCREEN.
  CASE sscrfields-ucomm.
    WHEN 'WORD_START'.
      CHECK word-handle <> -1.
      CHECK word-header = space.
      CREATE OBJECT   word  'Word.Basic'.
      CALL METHOD  OF word  'AppShow'.
    WHEN 'EXCEL_START'.
      CHECK excel-handle = 0.
      CHECK excel-header = space.
      CREATE OBJECT   excel 'Excel.Application'.
      SET PROPERTY OF excel 'Visible' = 1.
      GET PROPERTY OF excel 'Workbooks' = book.
      CALL METHOD  OF book  'Open' = rc
        EXPORTING #1 = 'C:\temp\Table.xls'.
    WHEN 'WORD_STOP'.
      CALL METHOD OF word 'AppClose'.
      FREE OBJECT word.
      CLEAR: word-handle, word-header.
    WHEN 'EXCEL_STOP'.
      CALL METHOD OF  excel 'Quit'.
      FREE OBJECT excel.
      CLEAR: excel-handle, excel-header.
    WHEN OTHERS.
      LEAVE PROGRAM.
  ENDCASE.

CL_GUI_FRONTEND_SERVICES - Frontend Services ROGBILLS - Synchronize billing plans
Diese Dokumentation steht unter dem Copyright der SAP AG.

Length: 8534 Date: 20120526 Time: 232907 triton ( 164 ms )

Schnelle Adresssuche

Einfache Berechtigungen in SAP

Performance-Optimierung

Single-Sign-On ohne Lizenzkosten